たかはしです。


先日をしていたインジケータのパラメータを最適化するひな形のEAを作ってみました。


最適化したいインジケータの内容に沿っておもいっきりカスタマイズする必要がありますが、一応最適化自体は可能です(・_・;)


使い方が少々ややこしいので、下記に説明していきます。


ダウンロード

とりあえずダウンロードして下さい。
ParameterOptimization.mq4


設置方法

環境によって複雑な場所にフォルダがあるので、この方法でダウンロードしたファイルを設置してください。
※最適化したいインジケーターはIndicatorフォルダに入っている事を前提とします。

MetaEditorを開く

スクリーンショット 2015-05-05 23.10.31
赤枠で囲んでいるボタンをクリックします。


Expertsフォルダを開く

スクリーンショット 2015-05-05 23.10.05
赤枠で囲んでいる「OpenFolder」をクリックします。


EAファイルの設置

ダウンロードしたファイルをExpertsフォルダに設置します。


カスタマイズ方法

コード全体

お粗末なコードで申し訳ないけど、一応目的は果たせますw

//+------------------------------------------------------------------+
//|                                        ParameterOptimization.mq4 |
//|       Copyright (C)2015 FX取引に関するあれこれ All Rights Reserved. |
//|                                              http://www.mql4.com |
//+------------------------------------------------------------------+
#property copyright   "Copyright (C) 2015 FX取引に関するあれこれ All Rights Reserved."
#property link        "http://fxtrading.greeds.net"

/*▼EAのパラメータ▼*/
input double TP    =5000;
input double SL    =5000;
input double Lots  =0.1;
/*▲EAのパラメータ▲*/

/*▼インジケーターのパラメータ▼*/
input bool AlertsEnabled=false;
input double Step = 0.009;//was .01
input double Maximum = 0.2;
input int Precision = 7;
input int TimeFrame=0;
/*▲インジケーターのパラメータ▲*/

//+------------------------------------------------------------------+
//|メイン                                                              |
//+------------------------------------------------------------------+
void OnTick(void)
{
	int cnt,total;
	if(Bars<100)
	{
		Print("bars less than 100");
		return;
	}
	
	if(TP<10)
	{
		Print("TakeProfit less than 10");
		return;
	}
	
	/*▼最適化したいインジケータからデータを取得▼*/
	double out0_0 = iCustom(NULL,0,"Parabolic_trendchaser",AlertsEnabled,Step,Maximum,Precision,TimeFrame,0,1);
	double out0_1 = iCustom(NULL,0,"Parabolic_trendchaser",AlertsEnabled,Step,Maximum,Precision,TimeFrame,0,2);
	double out1_0 = iCustom(NULL,0,"Parabolic_trendchaser",AlertsEnabled,Step,Maximum,Precision,TimeFrame,1,1);
	double out1_1 = iCustom(NULL,0,"Parabolic_trendchaser",AlertsEnabled,Step,Maximum,Precision,TimeFrame,1,2);
	/*▲最適化したいインジケータからデータを取得▲*/
	
	total=OrdersTotal();
	
	if(total<1)
	{
		if(AccountFreeMargin()<(1000*Lots))
		{
			Print("We have no money. Free Margin = ",AccountFreeMargin());
			return;
		}
		
		/*買いエントリー*/
		if(out1_0>0 && out0_1>0)
		{
		   EntryL();
		}
		
		/*売りエントリー*/
		if(out0_0>0 && out1_1>0)
		{
   		EntryS();
   	}
	}

	for(cnt=0;cnt<total;cnt++)
	{
		if(!OrderSelect(cnt,SELECT_BY_POS,MODE_TRADES))
		continue;
		if(OrderType()<=OP_SELL &&   // check for opened position 
			OrderSymbol()==Symbol())  // check for symbol
		{
			if(OrderType()==OP_BUY)
			{
   		   /*買い決済*/
				if(out0_0>0 && out1_1>0)
				{
			   	SettlementL();
				   return;
				}
			}
			else // go to short position
			{
			   /*売り決済*/
				if(out1_0>0 && out0_1>0)
				{
   				SettlementS();
				   return;
				}
			}
		}
	}
}
void EntryL()
{
	int ticket = OrderSend(Symbol(),OP_BUY,Lots,Ask,3,Ask-TP*Point,Ask+TP*Point,"macd sample",16384,0,Green);
	if(ticket>0)
	{
		if(OrderSelect(ticket,SELECT_BY_TICKET,MODE_TRADES))
		Print("BUY order opened : ",OrderOpenPrice());
	}
	else	
	{
		Print("Error opening BUY order : ",GetLastError());
	}
  	return;
}
void EntryS()
{
	int ticket = OrderSend(Symbol(),OP_SELL,Lots,Bid,3,Bid+TP*Point,Bid-TP*Point,"macd sample",16384,0,Red);
	if(ticket>0)
	{
		if(OrderSelect(ticket,SELECT_BY_TICKET,MODE_TRADES))
		Print("SELL order opened : ",OrderOpenPrice());
	}
	else
	{
		Print("Error opening SELL order : ",GetLastError());
	}
   return;
}
void SettlementL()
{
	if(!OrderClose(OrderTicket(),OrderLots(),Bid,3,Violet))
	{
		Print("OrderClose error ",GetLastError());
	}
	return;
}
void SettlementS()
{
	if(!OrderClose(OrderTicket(),OrderLots(),Ask,3,Violet))
	{
	   Print("OrderClose error ",GetLastError());
	}
	return;
}



最適化するインジケータの取得

最適化するインジケーターからデータを拾う準備をします。
コードの15行目「▼インジケーターのパラメータ▼」にインジケータの入力項目をコピペします。
このパラメータで最適化を行います。

だいたい「input」「extern」って書いてあるやつがインジケータのパラメータです。



コードの41行目「▼最適化したいインジケータからデータを取得▼」でデータを取得します。

ちょっとややこしいけど、頑張って理解してください。


double out0_0 = iCustom(NULL,0,”Parabolic_trendchaser”,AlertsEnabled,Step,Maximum,Precision,TimeFrame,0,1);

double out0_0ってのはdouble型という小数点を扱える変数です。

out0_0にインジケータの値が入ります。



iCustom(NULL,0,”Parabolic_trendchaser”,AlertsEnabled,Step,Maximum,Precision,TimeFrame,0,1);

iCustomという関数を利用して最適化したいインジケータの値を取得します。

前から順番に説明します。



NULLの場所には通貨ペアを指定できますが、NULLで現在表示している画面の通貨ペアが自動的に設定されます。



0はタイムフレームで時間軸で、5分足なら5、1時間足なら60といった具合になりまして、0の場合は現在表示している時間軸が自動的に設定されます。



“Parabolic_trendchaser”は最適化したいインジケータの名前を設定します。

.ex4や.mq4は省略してください。



その後ろにはそのインジケータの入力パラメータをすべて設定します。

Parabolic_trendchaserの場合は「AlertsEnabled,Step,Maximum,Precision,TimeFrame」の5項目があるので、その通り設定しています。



最後から2番目の0は出力項目の順番です。
出力項目は画像やり方で確認できます。
スクリーンショット 2015-05-05 23.36.12
データウィンドウの下部に赤枠で表示されているのがインジケータの出力項目です。
上から0番目、1番目という風に数えます。



最後の1は最新の足からさかのぼる数です。
0は現在の足で、1は一つ前の足です。


0だとデータが変動するため、判定ロジックがぶれてしまうので、変更のない確定した直近のデータを用いるために一つ前の足のデータを利用します。


リアルタイム性を持たすなら0を使ってみても良いです。

安定性を持たすなら1とかが無難ですね。


上記コードではこの様になっています。
double out0_0 = iCustom(NULL,0,”Parabolic_trendchaser”,AlertsEnabled,Step,Maximum,Precision,TimeFrame,0,1);
double out0_1 = iCustom(NULL,0,”Parabolic_trendchaser”,AlertsEnabled,Step,Maximum,Precision,TimeFrame,0,2);
double out1_0 = iCustom(NULL,0,”Parabolic_trendchaser”,AlertsEnabled,Step,Maximum,Precision,TimeFrame,1,1);
double out1_1 = iCustom(NULL,0,”Parabolic_trendchaser”,AlertsEnabled,Step,Maximum,Precision,TimeFrame,1,2);


out0_0は1つ前の出力0番目の値を取得しています。
out0_1は2つ前の出力0番目の値を取得しています。
out1_0は1つ前の出力1番目の値を取得しています。
out1_1は2つ前の出力1番目の値を取得しています。

ちなみに出力0は売りのラインで出力1は買いのラインです。


エントリー判定箇所

コードの58行目「/*買いエントリー*/」で買い判定を行っています。

if(out1_0>0 && out0_1>0)
1つ前に買いラインが点灯し、2つ前は売りラインが点灯している状態ということは、転換したというふうにみなします。


if(out0_0>0 && out1_1>0)
売りも同じで1つ前に売りラインが点灯し、2つ前は買いラインが点灯していた状態です。


決済判定箇所

コードの80行目「/*買い決済*/」で決済判定を行っています。
基本的に売買サインの逆転で決済するように書いています。
内容的にはエントリー判定箇所に考え方と同じなので説明は省略します。


まとめ

コードの説明を言葉で説明するのって難しい(;´Д`)


ある程度わかっている人ならわかってくれるんだろうけど、コード自体見たことない人にとっては異世界の話のように感じると思いますw


ガリガリ書くまでは行かないけど、とりあえずコードの買い替えは必須ということなので、使える人はガンガン使ってください。


使えない人は勉強してもらうか、問い合わせから質問くれればサポートします。


では、みんなの最適値を願って今日はこのへんで失礼します(´∀`*)ノシ

この記事が気に入ったら
いいね ! しよう

Twitter で